home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 4
/
FM Towns Free Software Collection 4 - Disc 1.iso
/
t_os
/
booklike
/
knjpchk.bas
< prev
next >
Wrap
BASIC Source File
|
1991-10-18
|
1KB
|
44 lines
100 '
110 ' 漢字ドットチェック
120 ' 91.06.11 KD
130 '
140 ' 漢字1文字かJISコードを入力する
150 ' コードの前に&hは不要
160 ' 表示後何かキーを押すと再び入力出来る
170 ' リターンのみで終了
180 '
190 ON ERROR GOTO *ERR
200 DIM Y$(15)
210 Y$( 0)="1":Y$( 1)="2":Y$( 2)="3":Y$( 3)="4":Y$( 4)="5"
220 Y$( 5)="6":Y$( 6)="7":Y$( 7)="8":Y$( 8)="9":Y$( 9)=":"
230 Y$(10)=";":Y$(11)="<":Y$(12)="=":Y$(13)=">":Y$(14)="?"
240 Y$(15)="@"
250 *PTOP:CONSOLE 0,24,2:COLOR 7:CLS
260 INPUT "漢字 OR JISコード : ",A$
270 IF A$="" THEN *END
280 IF LEN(A$)=4 THEN GOSUB *CODECHECK:CODE=VAL("&h"+A$):A$=KNJ$(CODE)
290 SYMBOL(0,19*3),A$,1,1,7
300 GOSUB *DCHECK
310 TEMP$=INPUT$(1)
320 GOTO *PTOP
330 *ERR
340 RESUME *PTOP
350 *END
360 END
370 *DCHECK
380 COLOR 5:LOCATE 15,1:PRINT "123456789:;<=>?@";
390 FOR I=0 TO 15:LOCATE 13,I+2:PRINT Y$(I):NEXT:COLOR 7
400 FOR I=0 TO 15
410 FOR J=0 TO 15
420 IF POINT(I,19*3+J)=-1 THEN LOCATE I*2+15,J+2:PRINT "●"; ELSE LOCATE I*2+15,J+2:PRINT "○";
430 NEXT
440 NEXT
450 RETURN
460 *CODECHECK
465 ' コンパイラは小文字のa-fを認識しないので大文字に変換する
470 FOR I=1 TO 4
480 AA=ASC(MID$(A$,I))
490 IF AA>&H60 THEN MID$(A$,I,1)=CHR$(AA-&H20)
500 NEXT
510 RETURN